2.0&TBC宏教程

做个标记

QUOTE:

这个是宏教程贴!不是求宏贴!!

关于宏的部分此贴已经解释的很详细了,

仔细的读一读吧.

除非你认为自己不行.

没有绝对的小白,也没有绝对的达人,达人只是比小白领先一步而已.

当然,想永远当小白的请无视我,欢迎来喷.言尽于此.

——kristina

QUOTE:


注意!!!
饿。。。请不要无视克MM的话,关于直接求宏或者是在这里已经说明过的问题一律无视。并且我玩的是术士,对于其他职业的宏很多都是有心无力。
但是大家要是有哪里不明白的,或者宏不能正常运作却不知道问题出在哪里的可以直接跟贴询问,我会不定期回答。^@^

——生命的尽头-暮色

QUOTE:

更新日志:
07年7月8日:添加“如何写一个宏—术士实例讲解”以及更改了动作条编号的说明。
07年7月5日:增加了3个新命令。

前言:

1、由于CastSpellByName()和TargetUnit()在2.0被禁用,所以2.0之前的大部分宏将无法使用。现在,宏写法也有了很大的变化。没有宏可以检查Buff,Debuff,冷却,血量,魔法,怒气,能量。但是,大家也不用太惋惜,现在的宏可以实现许多新的功能,并且非常强大。
2、—在使用一些宏之前请先检查你的按键设置。系统默认Ctrl+1到10是使用宠物技能栏,而Shift+1到6是选定动作条。有些宏在使用时由于自己的设置有可能和这些默认的按键冲突,解决办法为改宏或者改掉系统默认的按键设置。
— 后面带“[option]”的命令都是可以加条件判定的命令!貌似只有个别的几个不可加条件判定。。。=。=!
3、wowwiki首页:http://www.wowwiki.com/Main_Page
wiki的2.0宏首页:http://www.wowwiki.com/HOWTO:_Make_a_Macro
4、把这篇帖子一字不漏的看完,那么99%的宏你都可以自己写了。
5、感谢gzkuru的补充~

写宏很简单,只要肯研究。

QUOTE:

如何写一个宏—术士实例讲解

壹:初步制作
恩。。。因为我是个恶魔术士,所以我现在想写个瞬招胖子牺牲宏。
第一步,用“/cast”来施放“牺牲”:
/cast 牺牲
这样就写好了,“/cast”也就是“/施放”,作用是可以让你在宏内施放一个技能。而“牺牲”,是术士宠物的一个技能。

第二步,光有牺牲没有瞬招怎么行~牺牲完胖子我还想瞬招一个出来呢。
/cast 恶魔支配
“恶魔支配”,术士无公共CD法术。

第三步,光有瞬招却不招宠物是不行的,所以。。。
/cast 召唤虚空行者
“召唤虚空行者”,不用解释了吧。。。。。。。。

第四步,现在“牺牲”、“恶魔支配”、“召唤虚空行者”都写好了,下面把他们组合起来。
/cast 牺牲
/cast 恶魔支配
/cast 召唤虚空行者
组合起来之后就是这样了,这个宏可以先牺牲胖子,然后使用恶魔支配,然后召唤虚空。一共按键3次。
注意:并不是所有宏都可以这样写的!原因是牺牲和恶魔支配,一个是宠物技能,一个是无公共CD技能,都不占用公共CD,所以这个“傻瓜”格式的宏才会有效。同样,所有无公共CD的技能、物品和宠物技能,都可以只加一个占用公共CD的技能写在一个无任何条件的宏中。比如先使用护符,再放技能的宏!

贰:添加条件
虽然有了瞬招牺牲宏,但是我不想让这个宏单独占我一个宝贵的快捷键。。。所以,我要给这个宏添加几个条件让它在适当的时候能做出适当的动作。具体如下。

第一步:要是这个宏能在我需要瞬招牺牲的时候才会起作用该多好~~~所以我想到了只有在没有宠物的情况下在使用恶魔支配所以,上面的宏就变成了下面这样。
/cast 牺牲
/cast [nopet]恶魔支配
/cast 召唤虚空行者
这个宏里面多了一个“[nopet]”。“nopet”是条件,也就是“没有宠物”的意思。而“[]”的作用就是告诉WOW都有什么是条件,所有写在“[]”里面的东西都是条件。

第二步:我觉得光是在没有宠物的情况下使用“恶魔支配”还是不能满足我的需要,因为使用完牺牲之后宠物并没有消失,而是死亡状态,所以,我又给宏加了一个条件。如下~
/cast 牺牲
/cast [nopet][target=pet,dead]恶魔支配
/cast 召唤虚空行者
这次,宏里面添加了“target=pet,dead”这个条件,但是实际上这是两个条件。首先,“taregt=pet”是一个条件,作用是把你的隐藏目标(隐藏目标其实是我自己起的名字,这个条件的意思就是并不会改变你当前的目标,并且选择一个目标做为将要进行的动作的目标)指向你的宠物。而“dead”的作用就是判断目标是否死亡。而“,”半角逗号,也就是不用任何输入法打出来的逗号,作用为“并且”存在着,所以“target=pet,dead”的实际意思是“把隐藏目标指向你的宠物,并且判断其是否死亡”,白话一点就是“判断你的宠物是否死亡”。
还要说一点~“[nopet][target=pet,dead]”,前面的“[nopet]”和“[target=pet,dead]”的关系为“或者”,当两个“[]”连在一起写的时候都为“或者”。就是说当“[nopet]”不成立的时候会检查“[target=pet,dead]”是否成立,如果“[target=pet,dead]”也不成立那么这个法术是不会被施放的。相反,只要这两组条件中有一个是成立的,那么这个技能就会被施放,这就是“并且”的作用。

基本内容就这么多,个人感觉真的是很少很少,并且非常简单。献给喜欢宏并且想学习写宏的人。

一些基本知识
==========================================================
==========================================================

QUOTE:

身上各个部位编号:
1:头
2:颈
3:肩
4:衬衣
5:胸
6:腰带
7:腿
8:脚
9:手腕
10:手套
11:手指1
12:手指2
13:饰品1
14:饰品2
15:背
16:主手
17:副手
18:远程武器

动作条名称及编号:
主动作条1:ActionButton
主动作条2:不知道。。。。。。。
主动作条3(右1):MultiBarRightButton
主动作条4(右2):MultiBarLeftButton
主动作条5(右下):MultiBarBottomRightButton
主动作条6(左下):MultiBarBottomLeftButton
每个动作条的按钮从左至右都是1~12。
背包及包裹格子编号:
背包从右到左的编号分别是:4、3、2、1、0~
包裹格子的编号是从左至右排列,一个包的第一行分别是:1、2、3、4~
然后是包裹第2行:5、6、7、8~下面几行依次类推。

姿态编号:
|   战士   |  德鲁伊  |  牧师  |  盗贼  | 萨满祭祀
------------------------------------------
姿态 1 |   战斗   |  熊  | 暗影形态 |   潜行  | 幽魂之狼
姿态 2 |   防御   |  海豹 |     |     |
姿态 3 |   狂暴   |  猫  |     |     |
姿态 4 |             | 旅行  |     |     |
姿态 5 |             | 枭兽/树 |     |     |
姿态 6 |             |  飞行 |     |     |

从2.0开始宏内可用的条件:

QUOTE:

help—判断目标是否为友善;
比如“/cast [help]治疗术”,如果目标为友善那么施放治疗术。

harm—判断目标是否为敌对;
比如“/cast [harm]惩击”,如果目标为敌对那么施放惩击。

party—判断目标是否在本小队中;
比如“/cast [party]治疗术”,如果目标在本小队中那么施放治疗术。

raid—判断目标是否在团队中;
比如“/cast [raid]治疗术”,如果目标在本团队中那么施放治疗术。

group—判断自己是否在一个队伍中(小队或团队);
比如“/cast [group]治疗导言”,如果自己在一个队伍中那么施放治疗导言。

group:party/raid判断自己是否在一个指定的集体中:小队/团队;
比如“/cast [group:raid]治疗导言;[group:party]快速治疗”,如果在团队中就施放导言,在小队中就施放快速。

combat—判断你是否在战斗中;
比如“/cast [combat]消失;[nocombat]潜行”,如果在战斗就消失,不在战斗就潜行。

stancestance:#—判断你是否在姿态中或是否在指定姿态中。#为数字,也就是姿态编号。
比如“/cast [stance]精神鞭挞”,如果在暗影形态就施放鞭挞。“/cast [stance:3]潜行”,如果在猫形态就潜行。

stealth—判断你是否在潜行;
比如“/cast [stealth]背刺;邪恶攻击”,如果在潜行就用背刺,否则邪恶攻击。

modifier或modifier:x—x可为shift、ctrl、alt 或者是它们的组合,判断某个或某几个按键是否被按下。

equipped:<item>—判断某件物品是否在装备中。<item>可以是装备栏编号、装备分类(武器、副手。。。)、装备子类(双手剑、法仗等等。。。)

target=<unit>—可以把技能目标指定为任何有效的目标,并且可以另你不丢失当前目标!<unit>还可以为“none”,用来指定没有目标的时候。“player”,用来指定只对自己施放。比如“/use [target=player] 厚符文布绷带”,无论任何时候都只对自己使用绷带。关于“self”,这个条件在使用时经多人测试都会报错,原因不明,所以暂时大家先不要用。

actionbar:<number>—判断当前动作条是否被列出。<number>可为1、2、3、4、5、6

pet:<pet type 或 pet name>—pet type为宠物类型;pet name为宠物名字。如果不填写宠物类型或名字则判断宠物是否存在。

mounted—判断是否在坐骑上。

swimming—判断是否在游泳。

flying—判断是否在飞行中。

outdoors—判断你是否在室外。

indoors—判断你是否在室内。

button:<#>—判断某个特定按钮是否被用来触发技能。<#>可为1(鼠标左键)、2(鼠标右键)、3(鼠标按键3,也就是鼠标滚轮向下按,不是向上滚也不是向下滚)、4(鼠标按键4,多键鼠标专用)、5(鼠标按键5,多键鼠标专用)。默认为1。

channelingchanneling:法术名称—判断你是否在引导法术或是否在引导指定的法术。
比如“/cast [nochanneling:奥术飞弹]奥术飞弹”,在这个例子里我把“channeling:奥术飞弹”前面加了“no”,所以这个宏的意思就变成了如果没有在引导奥术飞弹,那么施放奥术飞弹,避免浪费~~~

exists—判断特定目标是否存在。

dead—判断目标是否死亡。请注意,这个是判断目标是否死亡。如果你想判断你自己的宠物是否死亡就要写成这样“[target=pet,dead]”。
比如“/cast [target=pet,dead]复活宠物(猎人的复活宠物技能。。。)”。这个宏的意思就是如果你的宠物死亡了那么施放复活宠物。

equipped:装备名称/类型/子类型—判断某件装备是否在装备中。
比如“/cast [equipped:魔杖] 射击”,这个宏的意思是如果装备魔杖就使用射击。

==========================================================
==========================================================

一些命令的讲解及应用
施放法术相关
———————————————————————————————————–
———————————————————————————————————–

QUOTE:

/cast [option]
简单的说就是/施放,并且使用这个命令的宏只有一个法术会被施放。现在的这个命令可以加入条件来判定法术是否被施放。比如“/cast [help,combat] 快速治疗”,这个宏的意思是当目标为友善,并且在战斗中,那么施放快速治疗。
———————————————————————————————————–
———————————————————————————————————–
/castsequence [option]
连续点击可以按顺序施放指定法术。一个法术施放失败,后面的法术就不会被施放。
专用的条件选相(只有在做这个命令的条件时才会有这样的功用):reset=<#>或target或combat或它们的组合,其他同“/cast”。简单介绍一下<#>/target/combat的作用。
<#>—代表数字,一般都是1到1800,单位为秒。/castsequence reset=120 部落徽记,亡灵意志,这个宏的功能是先使用部落徽记,然后使用亡灵意志。如果120秒后亡灵意志依然没有被施放那么还是使用部落徽记。但是,reset=<#>永远都是在你施放完最后一个法术的时候开始记时。
target—切换目标时重至宏。
combat—战斗开始时重至宏。
比如“/castsequence reset=30/target/combat 腐蚀术,痛苦诅咒,生命虹吸”,意思是依次施放腐蚀、痛苦、虹吸,当最后一个法术施放完(也就是虹吸)30秒之后,或者切换目标,或者脱离战斗都会使序列重至,也就是从头开始。
———————————————————————————————————–
———————————————————————————————————–
/castrandom [option]
随机施放法术,比如“/castrandom 变形术:猪,变形术:羊,变形术:龟”。(我变~我变~我变变变!)
———————————————————————————————————–
———————————————————————————————————–

所有条件都可以在前面加“no”来达到相反的效果!比如“nocombat”,判断你是否不在战斗;“nomodifier”,意思是alt、ctrl、shift都没被按下。
“,”相当于以前的and。比如“/cast [help,combat]快速治疗”,这句的意思就是目标为友方并且在战斗中时使用快速治疗。
“/”相当于以前的or。比如“/castsequence reset=combat/target 腐蚀术,痛苦诅咒”,这句的意思就是当你脱离战斗或切换目标时宏重至,也就是再次从第一个法术开始施放。
几组条件可以以“或者”的形式存在。
比如(以下引用自gzkuru的发表):/cast [help] [target=player] [target=targettarget, help] 强效治疗术 --目标是自己,施放强效治疗术;“或者”目标可以治疗,施放强效治疗术;“或者”目标的目标可以治疗,则对目标的目标施放强效治疗术。

———————————————————————————————————–
———————————————————————————————————–

物品&装备

QUOTE:

———————————————————————————————————–
———————————————————————————————————–
/use [option]
使用物品或装备,不再需要像以前一样指定包裹或动作条编号了。比如“/use 厚符文布绷带”。
———————————————————————————————————–
———————————————————————————————————–
/userandom [option]
随即使用指定的几件物品。比如“/userandom [nomounted] 黑色作战科多兽,死亡军马的缰绳,霜狼嗥叫者的号角,迅捷绿色迅猛龙
———————————————————————————————————–
———————————————————————————————————–
/equip [option]
直接举例说明吧。“/equip [noequiped:复仇法袍]复仇法袍”,意思是如果没装备复仇法袍就把复仇法袍装备上。
———————————————————————————————————–
———————————————————————————————————–
/equipslot [option]
这个功能和上面那个类似。但是这个命令主要是为了武器、戒指等可以装备两件的装备而诞生的。
比如:
/equipslot [equiped:多彩之剑] 16 毁灭之刃
/equipslot [equiped:残忍利刃] 17 熔火犬牙
/equipslot [equiped:毁灭之刃] 16 多彩之剑
/equipslot [equiped:熔火犬牙] 17 残忍利刃
这个宏可以把多彩和毁灭、残忍和狗牙互换。“/equipslot”在这里主要就是区分主副手,让宏可以把装备穿到正确的位置。
———————————————————————————————————–
———————————————————————————————————–

目标选定相关

QUOTE:

———————————————————————————————————–
———————————————————————————————————–
/targe [option]
可以用来选定指定的目标,比如“/targe player”,这个宏会把你的目标选定为你自己。
可用目标:
人物&名字—比如“/target 生命的尽头”那么这个宏就会把目标选定为名字为“生命的尽头”的玩家了(也就是我了),宠物也是如此。如果你在战场,还可以把人物名字后面加上“-服务器名称”,比如“生命的尽头-暮色森林”,这样就选中了“暮色森林”服务器的“生命的尽头”了。
队友&队友宠物:
party1第1个队友
partypet1第一个队友的宠物
party2第2个队友
partypet2第二个队友的宠物
party3第3个队友
partypet3第三个队友的宠物
party4第4个队友
partypet4第四个队友的宠物
raidNraidpetN—N可为1到40。
mouseover—鼠标经过的目标,或者刚刚经过的目标。比如你现在已经选定了一个目标,同时你把鼠标移到另一个人的身上,然后使用宏“/cast [target=mouseover]恐惧术”,这时被恐惧的人就是你鼠标指向的人而非你的当前目标。
———————————————————————————————————–
———————————————————————————————————–
/targetenemy [option]
选定一个敌对目标。
———————————————————————————————————–
———————————————————————————————————–
/targetfriend [option]
选定一个友善目标。
———————————————————————————————————–
———————————————————————————————————–
/targetparty [option]
选定一个小队队友为目标。
———————————————————————————————————–
———————————————————————————————————–
/targetraid [option]
选定一个团队队友为目标。
———————————————————————————————————–
———————————————————————————————————–
/targetlasttarget [option]
选定你的最后一个目标。
———————————————————————————————————–
———————————————————————————————————–
/targetlastenemy [option]
选定最后一个对你有敌意的目标。
———————————————————————————————————–
———————————————————————————————————–
/assist [option]
协助~同“/协助”~可选单位同“/target”。
———————————————————————————————————–
———————————————————————————————————–
/focus [option]
一直锁定一个目标~比如把这个命令和宠物攻击结合做一个宏。再比如你当前的宠物是MM,并且用这个宏让MM去攻击一个战士,然后你切换了目标,并让MM施放诱惑,这时MM诱惑的目标不会是你当前的目标,而是刚才被锁定的那个战士。
/clearfocus [option]
取消当前被锁定的目标。
———————————————————————————————————–
———————————————————————————————————–

宠物相关

QUOTE:

———————————————————————————————————–
———————————————————————————————————–
/petattack [option]
让宠物开始攻击一个目标。
———————————————————————————————————–
———————————————————————————————————–
/petstay [option]
让宠物停在原地。
———————————————————————————————————–
———————————————————————————————————–
/petfollow [option]
让宠物跟随自己。
———————————————————————————————————–
———————————————————————————————————–
/petpassive [option]
让宠物进入被动状态。
———————————————————————————————————–
———————————————————————————————————–
/petdefensive [option]
让宠物进入防御状态。
———————————————————————————————————–
———————————————————————————————————–
/petaggressive [option]
让宠物进入攻击状态。
———————————————————————————————————–
———————————————————————————————————–
/petautocaston [option] 法术名称
宠物法术自动施放开启。
———————————————————————————————————–
———————————————————————————————————–
/petautocastoff [option] 法术名称
宠物法术自动施放关闭。
———————————————————————————————————–
———————————————————————————————————–

其他

QUOTE:

———————————————————————————————————–
———————————————————————————————————–
/startattack
开始攻击。。。
———————————————————————————————————–
———————————————————————————————————–
/stopattack
停止攻击。。。
———————————————————————————————————–
———————————————————————————————————–
# show <法术名称/物品名称>
这个命令可以让你的宏显示指定法术或物品的图标(技能冷却、物品数量、施法材料数量),前提是你的宏必须使用“?”这个图标。
———————————————————————————————————–
———————————————————————————————————–
#showtooltip <法术名称/物品名称>
这个命令可以让你的宏显示指定法术或物品的图标(技能冷却、物品数量、施法材料数量),并且显示物品或法术的详细说明。前提是你的宏必须使用“?”这个图标。
———————————————————————————————————–
———————————————————————————————————–
/cancelaura [option]
取消BUFF~比如“/cancelaura 奥术智慧”。
———————————————————————————————————–
———————————————————————————————————–
/cancleform [option]
取消某个姿态。比如“/cancleform 巨熊形态”,如果一个德鲁伊在巨熊形态时使用这个宏那么他就会取消形态变回人形。对于战士这个宏是不可以使用的,因为战士时刻都是在一个姿态中,不可取消。。。。。。
———————————————————————————————————–
———————————————————————————————————–
/stopmacro [option]
停止宏,可加条件判定。比如:
/cast [harm] 变形术
/stopmacro [noharm]
/p 正在把%t變羊!別去碰它!
如果你的目标不是敌对,那么按这个宏就不会说话。
———————————————————————————————————–
———————————————————————————————————–
/click [option]
点击?貌似是的。和“/cast”一样何以加事件判断。先介绍一下下面的两个参数。
ActionButton1这里的1可以改为1-72~也就是你的动作条第一个按钮到第72个按钮。当然,是在你没有使用任何动作条插件的情况下。具体请参照上面的技能栏编号说明。如果你使用了动作条插件,比如“zBar”,并且设置动作条最大按钮数量为12。那么“zBar动作条1”的技能栏编号就是73-84~“zBar动作条2”的技能栏编号就是85-96~依次类推,一般情况下任何动作条都是这样的。(我只是说一般情况下。。。不排除例外)
PetActionButton11可以改为1-10任何一个数,意思就是宠物技能栏的1-10。
下面举个例子:
比如“/click [pet:虚空行者]PetActionButton1”这个宏的意思是如果当前宠物是虚空行者,那么点击宠物技能栏1。这个命令一般都是和下面的两个命令结合使用!
再举个宏套宏的高级例子:
1号宏:
/click [pet]ActionButton1
/click [nopet]ActionButton2
2号宏(对应/click [pet]ActionButton1):
/cast 火焰之盾
/cast 牺牲
/cast 诱惑
/cast 拦截
/cast [harm]法术封锁
/cast [modifier:alt,target=player][help]吞噬魔法
3号宏(对应/click [nopet]ActionButton2)
/cast [nomodifier]召唤虚空行者;[modifier:ctrl]召唤魅魔;[modifier:alt]召唤地狱猎犬;[modifier:shift]召唤恶魔卫士;[nomodifier,button:2]召唤小鬼
要使用这个宏,首先要把2号和3号宏放到指定的位置。
效果:首先这个宏会判断你有没有宠物,有就使用宠物的法术,没有就召唤宠物。结合上面所说过的,不难看出这个宏的意思。(哦~~~~~~原来“/click”还可以这样用啊~~~~~~~~~~)
———————————————————————————————————–
———————————————————————————————————–
/stopcasting [option]
用来打断当前施法。比如你当前正在施放一个需要吟唱类法术(比如火球术),使用“/stopcasting”,法术被中断了。。。。=。=!举这个例子目的只为说明他的作用。当一个法师在吟唱大火球的时候,突然发现敌人解了他的羊正要把他变样。。。那么,这个宏就是时候使用了:
/stopcasting
/cast 法术反制
这个宏会立刻停止你当前的施法并且施放法术反制。个人感觉它比自己移动一下或者跳一下都要好用的多!想具体因为什么就最好自己进游戏试验一下。
这个命令还有一个特别重要的作用。就是可以把无公共CD的多个法术、使用物品和一个需要公共CD的法术连贯起来施放。也就是一个多开宏的中心部分!下面给出一个例子:
/use 13
/stopcasting
/cast 气定神闲
/stopcasting
/cast 炎爆术
这就是一个典型的多开宏。如果没有“/stopcasting”,这个宏就需要点3次才能实现功能。
———————————————————————————————————–
———————————————————————————————————–
/dismount [option]
下马。。。同样可以加入条件判定~并且。。。。。下马的速度不是一般的快~~ =。=!!!
———————————————————————————————————–
———————————————————————————————————–
/run
…作用不明。
———————————————————————————————————–
———————————————————————————————————–
/in N /频道 内容
延迟说话。N为数字,单位为秒。比如“/in 1 /p 说什么好呢”,这个宏的意思是“1秒后在小队内说:说什么好呢”。
———————————————————————————————————–
———————————————————————————————————–
/swapactionbar [option] <动作条编号> <动作条编号>
可以让两个动作条互换~~~~~没什么难理解的吧。
———————————————————————————————————–
———————————————————————————————————–
/changeactionbar [option] <动作条编号>
可以翻转到你指定的动作条。
———————————————————————————————————–
———————————————————————————————————–
/script SetCVar(“targetNearestDistance”,10)
其实这不是什么命令,而是一个宏。作用是把搜索范围规定为10码(其实就是规定了范围的TAB~),注意,不是暂时的。当然,要使用这个宏还要在中间加上寻找目标的命令以及在后面把搜索范围再改回来。
比如:
/script SetCVar(“targetNearestDistance”,5)
/targetlastenemy
/script SetCVar(“targetNearestDistance”,50)
/cast 摔拌
/targetlasttarget
/cast 自动射击
这只是一个例子,实际应用会不会出现问题我没有测试过。因为我是个术士。
作用是搜索近战范围内的敌人使用摔拌,然后再选定之前的目标并打开自动射击。

———————————————————————————————————–
———————————————————————————————————–

各职业通用宏

QUOTE:

/console SET targetNearestDistance “50”
将“TAB”能选定目标的最远距离改为50码。

/console SET targetNearestDistanceRadius “50”
将“TAB”能选定身后目标的最远距离设为50码,不过并不推荐这么做,20就够了。

/console SET profanityFilter “0”
去掉系统中的敏感词语屏蔽。

/script if UnitClass(“target”)==”法师” then SendChatMessage(“你好,给点水和面包好么?谢谢~~~”,”Whisper”,”兽人语”,UnitName”Target”);if IsAltKeyDown() then InitiateTrade(“target”);end;end;
M语要水宏。可以分辨职业,不是法师就不会说话。并且可以修改成要其他BUFF的宏。理论上还可以用/click来实现一个判断职业要BUFF的套宏。

/use [harm,target=player] 厚符文布绷带; 厚符文布绷带
summer699编写,不喜欢打开“自动自我施法”的人可以用这个宏。

/use [target=player] 厚符文布绷带
无论目标是谁都对自己使用绷带

# show 特效治疗石
/stopcasting
/use [combat]特效治疗石
/use [combat]作战治疗药水
/use [combat]特效治疗药水
/use [combat]强效治疗石
/cast [nocombat,noharm,button:2]制造治疗石; [button:3]制造治疗石(等级 4)
一键吃药水宏,不在战斗中是不会吃的。如果不是术士可以把制造石头的那句删除,也就是最后一行。

/targetlasttarget
/cast 亡灵意志
被恐惧后会丢失目标,这个宏的作用就是让你在用亡灵意志的同时选定最后一个目标,也就是刚刚丢失的那个目标。

/use 13
/stopcasting
/cast 法术名称
/stopcasting
/cast 法术名称
这个宏就是典型的多开宏,开饰品+一个无公共CD的法术+一个高伤害法术。

/stopcasting
/use XX手雷
这是一个手雷宏。点击使用手雷,再点击取消手雷并重新回到区域选择。

/script for j=1,10 do PickupInventoryItem(j); PickupContainerItem(0, j); end
/script for j=16,18 do PickupInventoryItem(j); PickupContainerItem(0, j-5); end
/script PickupInventoryItem(18);
一键脱全身装备。

全文完~~~

Leave a Reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.

猫言猫语 © 2007-2014 Frontier Theme